ShowCase
1. Карточка баннера
Описание:
баннер с XML-контеном (изображения, текст).
Тип кода:
фреймовый, Poster, Ajax, Extension.
Подробнее:
ShowCase представляет собой Flash-баннер, который показывает изображение и подпись к нему. При загрузке баннера показывается одно изображение, при следующей загрузке баннера покажется другое изображение. При клике по разным изображениям происходит переход на разные URL-адреса. ShowCase — это обычный Flash-ролик необходимого размера, который вызывает XML-файл, созданный специально для конкретного баннера и содержащий ссылки на изображения, ссылки для кликов и описание. Изображения и XML-файл располагаются на стороннем сервере. Таким образом, учитываются показы Flash-баннера и сумма кликов по всем изображениям в баннере. То есть, в статистике баннера будет сумма всех показов/кликов.
Обсчёт внешними системами:
Примечание: В случае необходимости показывать баннер при доскролле до баннерного места, можно воспользоваться кодом Poster или специальным кодом Ajax. В остальных случаях используйте стандартные коды Ajax или Extension.
2. Подготовка баннера
2.1. Flash-ролик
В нужном кадре Flash-ролика пропишите следующий скрипт:
if (_root.ar_comppath == undefined) {
_root.ar_comppath = '';
}
function _rand(n){ // возвращает целое число в диапазоне [0..n]
return Math.round(Math.random()*n)
}
var reviews_xml:XML = new XML();//создать объект типа XML
reviews_xml.ignoreWhite = true;// игнорировать пустые строки
reviews_xml.onLoad = function(success:Boolean):Void {
if (success) {// XML пришёл успешно
var childItems:Array = reviews_xml.firstChild.childNodes;
// получаем случайный item из массива
childItems = childItems[_rand(childItems.length-1)].childNodes;
var r = {};// создать объект r, в который запишем все переменные
for (var i:Number = 0; i<childItems.length; i++) {
r[childItems[i].nodeName] = childItems[i].firstChild.nodeValue;
}
_root.link1 += r['ar_cgihref'];// в переменную _root.link1 дописать значение ar_cgihref (клик) из XML
_root.txt.text = r['ar_text'];// вывод текста из XML
if (r['ar_image'].indexOf('http://') != 0) {// если адрес изображения не начинается с http://, то это изображение загружено в баннер
r['ar_image'] = _root.ar_comppath+r['ar_image'];
}
// загружаем изображение в ролик pict
var mcLoader:MovieClipLoader = new MovieClipLoader();
var listener = {
onLoadInit:function (mc:MovieClip) {
mc._width = 200;
mc._height = 200;
}
};
mcLoader.addListener(listener);
mcLoader.loadClip(r['ar_image'],_root.pict);
} else {
trace("Unable to load external file.");// обработка ошибки, если XML не пришёл.
}
};
reviews_xml.load(_root.ar_comppath+'0.xml?'+Math.round(Math.random()*1000000));// вызываем XML
mc._width, mc._height — размеры изображения.
2.2. XML-файл
Пример XML-файла:
<?xml version="1.0" encoding="UTF-8"?>
<root>
<item>
<ar_image>http://example.com/soloway_200.png</ar_image>
<ar_text>«Соловей» — первый оператор селективной рекламы.</ar_text>
<ar_cgihref>http://www.soloway.ru/</ar_cgihref>
</item>
<item>
<ar_image>http://example.com/adriver1.gif</ar_image>
<ar_text>AdRiver — система управления интернет-рекламой номер один.</ar_text>
<ar_cgihref>http://www.adriver.ru</ar_cgihref>
</item>
<item>
<ar_image>http://example.com/rle.gif</ar_image>
<ar_text>RLE — крупнейшая баннерообменная сеть в Рунете.</ar_text>
<ar_cgihref>http://www.rle.ru/</ar_cgihref>
</item>
</root>
Здесь каждая часть item — это набор следующих составляющих:
ar_image
изображение
ar_text
текст
ar_cgihref
ссылка для клика
Части item в баннере для ротации выбираются случайным образом.
Примечание: При загрузке баннера, если XML-файл располагается на стороннем сервере, то добавьте обычный Flash-баннер нужного размера. Кликните загрузить баннер и загрузите компоненты баннера. В поле Линк Баннера можно указать дефолтный клик, чтобы баннер был кликабельным в том случае, если XML-файл не загрузится.